NSD_OnClick is triggered on focus

[stopthemess]

Is it a known behavior? How can I filter only click events?

My code looks similar to this:

code:


${NSD_CreateRadioButton} 1 2 3 4 $R1

Pop $R1

${NSD_OnClick} $R1 OnRadioClick

The callback runs when I click on the button and when I focus on it. I need only click events. Thanks.

[Anders]

Radio buttons are usually part of a group and you cannot focus a radio without selecting it. When you are notified you should just check which of the radios in the group is selected and take appropriate action.

In the most common case you don't even add a handler for a radio, you just check its state in the page leave callback function. Only catch the OnClick if you dynamically need to change something else on the page when the radio changes.

Internally in Windows check-boxes and radio buttons are implemented as buttons and nsDialogs just catches the BN_CLICKED event for OnClick.

[stopthemess]

> catches the BN_CLICKED event

Where can I see this code? I think the notification code is just not checked, and so BN_SETFOCUS triggers the callback as well.

You can reproduce by compiling this example and pressing tab several times, you'll see a message box while you shouldn't:
https://nsis.sourceforge.io/NsDialog...ton_selections

[Anders]

if (HIWORD(wParam) == BN_CLICKED && (ctl->type == NSCTL_BUTTON || ctl->type == NSCTL_LINK))

but why does it matter? Why is the focus event causing you trouble?

[stopthemess]

Because I switch between "Next >" and "Install" button text depending on the selected radio button. Now there's a bug in which I switch the text while the user didn't actually select the ratio button. I can work around it by checking whether the button is actually selected, but it's still a bug.

I found the code you referenced, but still the bug exists and I showed how to reproduce it easily. Looks like the code you provided is not involved in calling the callback in the scenario when focus is changed, but I didn't debug enough to understand why it's called.

[Anders]

Radio buttons sends BN_CLICKED when it gets focus, don't ask me why.

...generation of BN_CLICKED messages when the button receives focus.

You can do

PHP Code:

!define /IfNDef BM_SETDONTCLICK 0xF8 ; Vista and later only?
SendMessage $hMyRadio ${BM_SETDONTCLICK} 1 0 


but when you use radio buttons, it is important to use groups and "check" one as the default. After that you don't care why you got notified:

PHP Code:

!include nsDialogs.nsh
Page Custom pre
Function pre
nsDialogs::Create 1018
Pop $0
${NSD_CreateFirstRadioButton} 0 0 40% 6% "Configure $(^Name)"
Pop $1
${NSD_OnClick} $1 RadioChanged
${NSD_CreateAdditionalRadioButton} 0 12% 40% 6% "Just install now"
Pop $2
${NSD_OnClick} $2 RadioChanged
SendMessage $1 ${BM_CLICK} "" "" ; Set a default
nsDialogs::Show
FunctionEnd

Function RadioChanged
Pop $3
GetDlgItem $0 $hWndParent 1
${NSD_GetChecked} $1 $3
${If} $3 <> ${BST_UNCHECKED}
    ${NSD_SetText} $0 "$(^NextBtn)"
${Else}
    ${NSD_SetText} $0 "$(^InstallBtn)"
${EndIf}
FunctionEnd 


[stopthemess]

What the heck Microsoft, and BN_CLICKED's documentation has no mention of focus!

Thank you, BM_SETDONTCLICK fixes it nicely.